/* Ausgabe der "Rohdaten" des MPU6050 am Serial Monitor:
  Die Accelerometer- und Gyrometer-Werte in allen drei Richtungen sowie die Temperatur. 
  Die Register  werden beschrieben im Dokument "MPU-6000 and MPU-6050 Register Map and Descriptions Revision 4.2" */
  
  #include<Wire.h>
  const int MPU_Adr = 0x68;                     // Adresse des MPU-6050 an einem I2C-Bus
  int16_t AcX,AcY,AcZ,Tmp,GyX,GyY,GyZ;          // "16_t" gibt an, dass die integer-Variable 16 Bit haben soll... 
                                                // ...dadurch funktioniert es auch mit ESP8266 (integer ist dort 32 Bit lang).
  void setup()
  {
    Wire.begin();
    Wire.beginTransmission(MPU_Adr);
    Wire.write(0x6B);                           // Das Register 0x6B (PWR_MGMT_1) ansprechen
    Wire.write(0);                              // Den Wert 0 in dieses Register schreiben (wakes up the MPU-6050)
    Wire.endTransmission();                     // Die eigentliche Uebertragung geschieht erst jetzt
    Serial.begin(9600);                         // Serial Monitor auf 9600 Baud einstellen !
  }
  
  void loop()
  {
    Wire.beginTransmission(MPU_Adr);
    Wire.write(0x3B);                           // Das Register 0x3B (ACCEL_XOUT_H)ansprechen
    Wire.endTransmission();
    /* Es werden jetzt 14 Register ausgelesen, beginnend mit Reg 0x3B  ("0x": hexadezimaler Wert).
    Der Wert des jeweiligen hoeherwertigen Byte wird um 8 Stellen nach links verschoben. */
    Wire.requestFrom(MPU_Adr,14);              
    AcX=Wire.read()<<8|Wire.read();             // 0x3B (ACCEL_XOUT_H) & 0x3C (ACCEL_XOUT_L)    
    AcY=Wire.read()<<8|Wire.read();             // 0x3D (ACCEL_YOUT_H) & 0x3E (ACCEL_YOUT_L)
    AcZ=Wire.read()<<8|Wire.read();             // 0x3F (ACCEL_ZOUT_H) & 0x40 (ACCEL_ZOUT_L)
    Tmp=Wire.read()<<8|Wire.read();             // 0x41 (TEMP_OUT_H) & 0x42 (TEMP_OUT_L)
    GyX=Wire.read()<<8|Wire.read();             // 0x43 (GYRO_XOUT_H) & 0x44 (GYRO_XOUT_L)
    GyY=Wire.read()<<8|Wire.read();             // 0x45 (GYRO_YOUT_H) & 0x46 (GYRO_YOUT_L)
    GyZ=Wire.read()<<8|Wire.read();             // 0x47 (GYRO_ZOUT_H) & 0x48 (GYRO_ZOUT_L)
    
    Serial.print("AcX = "); Serial.print(AcX);
    Serial.print(" | AcY = "); Serial.print(AcY);
    Serial.print(" | AcZ = "); Serial.print(AcZ);
    Serial.print(" | Tmp = "); Serial.print(Tmp/340.00+36.53);  //siehe Seite 30 im Dokument  
    Serial.print(" | GyX = "); Serial.print(GyX);
    Serial.print(" | GyY = "); Serial.print(GyY);
    Serial.print(" | GyZ = "); Serial.println(GyZ);
    delay(2000);                  
  }